Koodit: QB: Taso

DEFINT A-Z

SCREEN 13

pehmeys = 5
nopeus = 1

DIM texture(128, 128) AS INTEGER, xx AS SINGLE, yy AS SINGLE, zz AS SINGLE
DIM l AS SINGLE, t AS SINGLE, xtab(320) AS SINGLE, p AS LONG

OUT &H3C8, 0
FOR i = 0 TO 255
 OUT &H3C9, i / 255 * 63
 OUT &H3C9, i / 255 * 40
 OUT &H3C9, i / 255 * 63
NEXT i

FOR y = 0 TO 128
 FOR x = 0 TO 128
  texture(x, y) = RND * 255
 NEXT x
NEXT y

FOR i = 0 TO pehmeys: GOSUB smooth: NEXT i
FOR i = 0 TO 320: xtab(i) = (i - 160) / 160: NEXT i

DEF SEG = &HA000

DO
 mz = mz + nopeus
 p = 0

 FOR y = 1 TO 100
  yy = (y - 100) / 100
  IF yy = 0 THEN yy = .01
  t = ABS(20 / yy)
  l = ((200 - t) / 200)
  IF l < 0 THEN l = 0
  ty = (.9 * t + mz) AND 127
  FOR x = 1 TO 320 STEP 2
   c = texture(xtab(x) * t AND 127, ty) * l
   POKE p, c
   POKE p + 1, c
   POKE 63999 - p, c
   POKE 63998 - p, c
   p = p + 2
  NEXT x
 NEXT y
LOOP

smooth:
FOR y = 0 TO 128
 FOR x = 0 TO 128
  c = texture(x, y) + texture(x - 1 AND 127, y) + texture(x + 1 AND 127, y)
  c = c + texture(x, y - 1 AND 127) + texture(x - 1 AND 127, y - 1 AND 127) + texture(x + 1 AND 127, y - 1 AND 127)
  c = c + texture(x, y + 1 AND 127) + texture(x - 1 AND 127, y + 1 AND 127) + texture(x + 1 AND 127, y + 1 AND 127)
  texture(x, y) = c / 9
 NEXT x
NEXT y
RETURN