Koodit: VB6: Yksittäisten bittien manipulointia

Option Explicit

' Enumeraatio, jotta kakkosen potensseja ei tarvitse muistella :)
Public Enum Bitit
    EnsimmäinenBitti = 1    ' 2^0
    ToinenBitti = 2         ' 2^1
    KolmasBitti = 4         ' 2^2
    NeljäsBitti = 8         ' 2^3
    ViidesBitti = 16        ' 2^4
    KuudesBitti = 32        ' 2^5
    SeitsemäsBitti = 64     ' 2^6
    KahdeksasBitti = 128    ' 2^7
End Enum

' Aliohjelma asettaa yhden bitin Muuttuja -parametriksi annetusta Byte -tyyppisestä
' muuttujasta joko todeksi (1) tai epätodeksi (0) , Arvo -parametrin mukaan. Minkä
' bitin, se määräytyy Monesko -parametrin mukaan.
'
' Huomaa, että aliohjelma muokkaa alkuperäistä parametriksi annettua muuttujaa sen
' sijaan, että tekisi siitä kopion ja palauttaisi sen.
Public Sub AsetaBitti(Monesko As Bitit, Arvo As Boolean, ByRef Muuttuja As Byte)
    If Arvo = True Then     ' Bitti käännetään päälle
        ' Suoritetaan Or Muuttujalle ja bittimaskille
        Muuttuja = Muuttuja Or Monesko
    Else                    ' Bitti käännetään pois
        ' Suoritetaan And Muuttujalle ja maskin käänteisarvolle
        Muuttuja = Muuttuja And 255 - Monesko
    End If
End Sub

' Funktio palauttaa True tai False sen mukaan, onko Muuttuja -parametriksi annetun
' Byte -tyyppisen muuttujan Monesko -parametrin mukainen bitti 1 vai 0.
Public Function HaeBitti(Monesko As Bitit, ByRef Muuttuja As Byte) As Boolean
    ' Suoritetaan And muuttujalle ja maskille, jos tulos on 0 bitti oli pois päältä,
    ' jos jotain muuta, bitti oli päällä.
    If (Muuttuja And Monesko) = 0 Then
        HaeBitti = False
    Else
        HaeBitti = True
    End If
End Function